home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
BMUG Revelations
/
BMUG Revelations.toast
/
Utilities
/
Network
/
QUE
/
Bridge
/
Que Script
Wrap
Text File
|
1989-07-19
|
4KB
|
164 lines
*
* Que Bridge Script
*
* 7/17/89 Version 1.0
*
* Copyright (c) 1988, 1989 Rob Kassel
*
* Permission to use, copy, modify, and distribute
* this software and its documentation for any purpose
* without fee is hereby granted, provided that the above
* copyright notice appear in all copies and that both that
* copyright notice and this permission notice appear in
* supporting documentation, and that the name of M.I.T. not
* be used in advertising or publicity pertaining to distribution
* of the software without specific, written prior permission.
* The authors and M.I.T. make no representations about the
* suitability of this software for any purpose. It is provided
* "as is" without express or implied warranty.
*
***********************************************
* CONNECT TO HOST
***********************************************
:IN
OOPS 60,FAILURE
***********************************************
* $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
* Add anything you need to negotiate the initial connection
* here. If the connection cannot be established, issue
* a FAILURE. If the connection is established, GOTO
* OPEN.
* $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
***********************************************
:OPEN
ALERT 1,LOGIN,login:
ALERT 2,TRYKILL,ZSRHKQV>
PAUSE 5
TYPE ^M
PAUSE 5
TYPE ^M
PAUSE 5
TYPE ^M
PAUSE 5
:TRYKILL
ALERT 1,OPEN,que mail transfer complete
ALERT 2,,
TYPE ^B^B^B^B^M
TYPE logout^M
PAUSE 3
TYPE logout^M
PAUSE 3
TYPE logout^M
PAUSE 3
ALERT 1,,
FAILURE
:LOGIN
ALERT 1,PASSWD,Password:
ALERT 2,,
TYPE «LOGID»^M
PAUSE 69
FAILURE
:PASSWD
ALERT 1,NOWIN,ZSRHKQV>
ALERT 2,FAILURE,incorrect
TYPE «PASSWORD»^M
PAUSE 69
FAILURE
:NOWIN
ALERT 1,,
ALERT 2,,
SUCCESS
***********************************************
* Get the next message if there is one.
***********************************************
:RECEIVE
OOPS 400,ABORTOUT
ALERT 1,NOMORE,No mail to read.
TYPE queread^M
WAIT Message in 5
ALERT 1,,
PAUSE 1
BUFFER ENDOFMESSAGETOMACQRLMT^MFrom M^MZSRHKQV
RECEIVE Subject:,X-Mac-To:,X-Mac-From:,<,>
TYPE rm readMsg^M
WAIT ZSRHKQV>
SUCCESS
***********************************************
* We're done reading mail.
***********************************************
:NOMORE
ALERT 1,,
FAILURE
***********************************************
* There was an error somewhere in receive.
***********************************************
:ABORTOUT
ALERT 1,,
TYPE ^B^B^B^B^M
FAILURE
***********************************************
* Send the next message.
***********************************************
:SEND
OOPS 400,FAILURE
ALERT 1,BADREPLY,Invalid User
TYPE quecheck «FROM»^M
WAIT ZSRHKQV>
ALERT 1,,
TYPE quesend^M
TYPE «ADDRESS»^L^M
TYPE Received: via Que with SCRIPT1.0^M
TYPE From: «FROM»^M
TYPE Subject: «TOPIC»^M
TYPE ^M
DUMP
TYPE ^M^D
WAIT ZSRHKQV>
SUCCESS
***********************************************
* Send another copy of the previous message.
***********************************************
:AGAIN
OOPS 400,FAILURE
TYPE quesend -a^M
TYPE «ADDRESS»^L^M
WAIT ZSRHKQV>
SUCCESS
***********************************************
* Punt sending if we can't reply to sender
***********************************************
:BADREPLY
ERRORINADDRESS
SUCCESS
***********************************************
* Log out of host.
***********************************************
:BYE
OOPS 20,SUCCESS
ALERT 1,LOGGEDOUT,que mail transfer complete
TYPE logout^M
PAUSE 3
TYPE logout^M
PAUSE 3
TYPE logout^M
PAUSE 3
:LOGGEDOUT
ALERT 1,,
***********************************************
* $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
* Add anything you need to negotiate closing the connection
* here. If the connection cannot be closed, issue
* a SUCCESS anyway.
* $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
***********************************************
SUCCESS